@echo off
setlocal EnableExtensions
chcp 65001 >nul
title HIS Auto Setup - Phong CNTT

net session >nul 2>&1
if not "%errorlevel%"=="0" (
  echo Dang yeu cau quyen Administrator...
  powershell.exe -NoLogo -NoProfile -ExecutionPolicy Bypass -Command "Start-Process -FilePath '%~f0' -Verb RunAs"
  exit /b
)

set "HIS_INSTALL_URL=https://setup.hungvc.vn/install.ps1?v=1.5.3"
set "HIS_LOCAL_SCRIPT=%~dp0install.ps1"
set "HIS_SCRIPT=%TEMP%\HIS-AutoSetup-v1.5.3.ps1"
set "HIS_TEMP_SCRIPT=1"
set "HIS_LICENSE_FILE="
for %%F in ("%~dp0*4.0*25092026*.docx") do if exist "%%~fF" if not defined HIS_LICENSE_FILE set "HIS_LICENSE_FILE=%%~fF"
del /q "%HIS_SCRIPT%" >nul 2>&1
echo Dang tai bo cai v1.5.3 moi nhat tu setup.hungvc.vn...

powershell.exe -NoLogo -NoProfile -ExecutionPolicy Bypass -Command "$ProgressPreference='SilentlyContinue'; [Net.ServicePointManager]::SecurityProtocol=[Net.SecurityProtocolType]::Tls12; Invoke-WebRequest -Uri $env:HIS_INSTALL_URL -OutFile $env:HIS_SCRIPT -UseBasicParsing"
if errorlevel 1 goto use_local_installer
if not exist "%HIS_SCRIPT%" goto use_local_installer
goto run_installer

:use_local_installer
if not exist "%HIS_LOCAL_SCRIPT%" goto download_failed
echo Khong tai duoc ban moi; dang dung install.ps1 ben canh run.cmd.
set "HIS_SCRIPT=%HIS_LOCAL_SCRIPT%"
set "HIS_TEMP_SCRIPT=0"

:run_installer
echo Dang chay HIS Auto Setup...
if defined HIS_LICENSE_FILE (
  echo Da tim thay tep DOCX giay phep canh run.cmd.
  powershell.exe -NoLogo -NoProfile -ExecutionPolicy Bypass -File "%HIS_SCRIPT%" -ISofHToolsLicenseFile "%HIS_LICENSE_FILE%"
) else if defined HIS_ISOFH_LICENSE_DOC_URL (
  echo Dang dung lien ket DOCX giay phep rieng.
  powershell.exe -NoLogo -NoProfile -ExecutionPolicy Bypass -File "%HIS_SCRIPT%" -ISofHToolsLicenseDocUrl "%HIS_ISOFH_LICENSE_DOC_URL%"
) else (
  powershell.exe -NoLogo -NoProfile -ExecutionPolicy Bypass -File "%HIS_SCRIPT%"
)
set "HIS_EXIT=%errorlevel%"

if "%HIS_TEMP_SCRIPT%"=="1" del /q "%HIS_SCRIPT%" >nul 2>&1

echo.
if "%HIS_EXIT%"=="0" (
  echo Hoan tat.
) else (
  echo Co loi xay ra. Ma loi: %HIS_EXIT%
)
pause
exit /b %HIS_EXIT%

:download_failed
echo.
echo Khong the tai install.ps1 tu %HIS_INSTALL_URL%.
echo Khong tim thay install.ps1 du phong ben canh run.cmd.
echo Vui long kiem tra ket noi Internet hoac tai install.ps1 thu cong.
pause
exit /b 1